*  JieJie Microelectronics H-Spice Model Library
*  Filename	:  JMSL1023AY _H v.20220623.txt
*  Product Name   :  JMSL1023AY  (SOT-223-3L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Jun24, 2022
*  Junction Temp (Tj): -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL1023AY D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.014
RS S 3 1E-006
RG G 2 1.9
CGS 3 G 7.64E-10
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 5E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 6.78398E-10 -3.65034E-11 2.64682E-12 -9.81837E-14 1.69432E-15 -1.35816E-17 4.11735E-20

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0       
+acm = 3                       VMAX = 1.0752E9               ETA = 1E-4        
+VTO = 2.3                     TOX = 8E-10                   NSUB = 3.55E15  
+KP = 110                      U0 = 424                      KAPPA = 0.1   
+GAMMA = 0.3                   PHI = 0.52                    THETA = 0.3  
+BEX = -1.05                   TCV = 2E-3                    DELTA = 96.220061    

.model DCGD D
+CJO = 1.7E-10                 VJ = 20                  M = 1.9      

.model DSUB D
+IS = 5E-13                    N = 1.02                      RS = 9E-3  
+BV = 106                      tlev = 0                      tlevc = 0   
+tref = 25                     eg = 1.11                     keg = 1   
+gap1 = 7.02E-4                gap2 = 1.108E3                xti = 1    
+cta = 0                       ctp = 0                       tcv = 0    
+tm1 = 0                       tm2 = 0                       tpb = 0   
+tphp = 0                      trs = 0                       ttt1 = 0  
+ttt2 = 0                      xtitun = 3  

.model DLIM D
+IS = 1E-4  
.ends JMSL1023AY

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************